mirror of
https://github.com/StevenBlack/hosts.git
synced 2026-07-01 02:36:52 +00:00
1960e05c52
At present, if a user uses ``networking.stevenBlockHosts.enable = true``
in tandem with ``networking.extraHosts``, the ``extraHosts`` will put be
put after which makes it very difficult to see the custom adds with even
the ``$PAGER`` operating a bit slow due to file size. I would propose
putting this project’s hosts at the end of the hosts file. Meaning:
.. code:: nix
{
networking = {
stevenBlockHosts.enable = true;
extraHosts = ''
127.0.0.1 myproject.localhost
'';
};
}
will now output
.. code::
127.0.0.1 localhost
::1 localhost
127.0.0.1 myproject.localhost
# Title: StevenBlack/hosts with the fakenews extension
#
# …
Format: text/x-rst
58 lines
2.1 KiB
Nix
58 lines
2.1 KiB
Nix
{
|
|
description = "Unified hosts file with base extensions.";
|
|
outputs = { self, nixpkgs, ... }@inputs:
|
|
let
|
|
forAllSystems = nixpkgs.lib.genAttrs nixpkgs.lib.platforms.unix;
|
|
|
|
nixpkgsFor = forAllSystems (system: import nixpkgs {
|
|
inherit system;
|
|
});
|
|
in
|
|
{
|
|
nixosModule = { config, ... }:
|
|
let
|
|
inherit (nixpkgs) lib;
|
|
cfg = config.networking.stevenBlackHosts;
|
|
alternatesList =
|
|
(lib.optional cfg.blockFakenews "fakenews")
|
|
++ (lib.optional cfg.blockGambling "gambling")
|
|
++ (lib.optional cfg.blockPorn "porn")
|
|
++ (lib.optional cfg.blockSocial "social");
|
|
alternatesPath = "alternates/" + builtins.concatStringsSep "-" alternatesList + "/";
|
|
in
|
|
{
|
|
options.networking.stevenBlackHosts = {
|
|
enable = lib.mkEnableOption "Steven Black's hosts file";
|
|
enableIPv6 = lib.mkEnableOption "IPv6 rules" // {
|
|
default = config.networking.enableIPv6;
|
|
defaultText = lib.literalExpression "config.networking.enableIPv6";
|
|
};
|
|
blockFakenews = lib.mkEnableOption "fakenews hosts entries";
|
|
blockGambling = lib.mkEnableOption "gambling hosts entries";
|
|
blockPorn = lib.mkEnableOption "porn hosts entries";
|
|
blockSocial = lib.mkEnableOption "social hosts entries";
|
|
};
|
|
config = lib.mkIf cfg.enable {
|
|
networking.extraHosts =
|
|
let
|
|
orig = builtins.readFile ("${self}/" + (lib.optionalString (alternatesList != []) alternatesPath) + "hosts");
|
|
ipv6 = builtins.replaceStrings [ "0.0.0.0" ] [ "::" ] orig;
|
|
in
|
|
lib.mkAfter (orig + (lib.optionalString cfg.enableIPv6 ("\n" + ipv6)));
|
|
};
|
|
};
|
|
|
|
devShells = forAllSystems (system:
|
|
let pkgs = nixpkgsFor.${system}; in
|
|
{
|
|
default = pkgs.mkShell {
|
|
buildInputs = with pkgs; [
|
|
python3
|
|
python3Packages.flake8
|
|
python3Packages.requests
|
|
];
|
|
};
|
|
});
|
|
};
|
|
}
|